Exchange Precompile

exchange.deposit(address(this), subaccountID, denom, amount);  

exchange.deposit(userAddress, subaccountID, denom, amount);  

exchange.approve(grantee, msgTypes, spendLimit, duration);  

exchange.revoke(grantee, msgTypes);  

exchange.allowance(grantee, granter, msgType);  

// SPDX-License-Identifier: MIT  
pragma solidity ^0.8.4;  
  
import "../src/Exchange.sol"; // IExchangeModule 인터페이스 포함  
import "../src/ExchangeTypes.sol"; // DerivativeOrder와 같은 필요한 구조체 포함  
  
contract ExchangeDemo {  
    address constant exchangeContract = 0x0000000000000000000000000000000000000065;  
    IExchangeModule exchange = IExchangeModule(exchangeContract);  
  
    /***************************************************************************  
     * precompile 직접 호출 (컨트랙트가 자체를 대신하여 작동)  
    ****************************************************************************/  
  
    /**  
     * @notice 컨트랙트 잔액에서 거래소 서브계정 중 하나로 자금을 입금합니다.  
     * @param subaccountID 대상 서브계정 ID(컨트랙트 주소에서 파생됨).  
     * @param denom 입금할 자산의 denom(예: "inj").  
     * @param amount 입금할 자산 수량.  
     * @return success 입금 성공 여부를 나타내는 불린.  
     */  
    function deposit(  
        string calldata subaccountID,  
        string calldata denom,  
        uint256 amount  
    ) external returns (bool) {  
        try exchange.deposit(address(this), subaccountID, denom, amount) returns (bool success) {  
            return success;  
        } catch Error(string memory reason) {  
            revert(string(abi.encodePacked("Deposit error: ", reason)));  
        } catch {  
            revert("Unknown error during deposit");  
        }  
    }  
  
    /**  
     * @notice 컨트랙트의 거래소 서브계정 중 하나에서 메인 잔액으로 자금을 출금합니다.  
     * @param subaccountID 소스 서브계정 ID.  
     * @param denom 출금할 자산의 denom.  
     * @param amount 출금할 자산 수량.  
     * @return success 출금 성공 여부를 나타내는 불린.  
     */  
    function withdraw(  
        string calldata subaccountID,  
        string calldata denom,  
        uint256 amount  
    ) external returns (bool) {  
        try exchange.withdraw(address(this), subaccountID, denom, amount) returns (bool success) {  
            return success;  
        } catch Error(string memory reason) {  
            revert(string(abi.encodePacked("Withdraw error: ", reason)));  
        } catch {  
            revert("Unknown error during withdraw");  
        }  
    }  
  
    /**  
     * @notice 이 컨트랙트의 주어진 서브계정에 대한 파생상품 포지션을 쿼리합니다.  
     * @param subaccountID 쿼리할 서브계정 ID.  
     * @return positions DerivativePosition 구조체 배열.  
     */  
    function subaccountPositions(  
        string calldata subaccountID  
    ) external view returns (IExchangeModule.DerivativePosition[] memory positions) {  
        // 참고: precompile을 호출하는 view 함수는 노드 구성에 따라 다르게 작동할 수 있습니다  
        // 온체인 상태의 경우 이것은 괜찮습니다. 오프체인 쿼리의 경우 직접 gRPC/API 쿼리가 종종 선호됩니다.  
        return exchange.subaccountPositions(subaccountID);  
    }  
  
    /**  
     * @notice 컨트랙트의 서브계정에서 새 파생상품 지정가 주문을 생성합니다.  
     * @param order 주문 세부 정보가 포함된 DerivativeOrder 구조체.  
     * @return response 주문 해시와 같은 세부 정보가 포함된 응답 구조체.  
     */  
    function createDerivativeLimitOrder(  
        IExchangeModule.DerivativeOrder calldata order  
    ) external returns (IExchangeModule.CreateDerivativeLimitOrderResponse memory response) {  
        try exchange.createDerivativeLimitOrder(address(this), order) returns (IExchangeModule.CreateDerivativeLimitOrderResponse memory resp) {  
            return resp;  
        } catch Error(string memory reason) {  
            revert(string(abi.encodePacked("CreateDerivativeLimitOrder error: ", reason)));  
        } catch {  
            revert("Unknown error during createDerivativeLimitOrder");  
        }  
    }  
}